Example: Poincaré-Bendixon

Define flow

xdot=x - y -x^3;
ydot =x + y -y^3;
flow={xdot,ydot}

fixsol=NSolve[flow==0,{x,y},Reals]

Make StreamPlot

streamp=Show[
StreamPlot[flow,{x,-2,2},{y,-2,2}],
Graphics[{PointSize[Large],Red,Point[{x,y}/.fixsol]}]
]

Transform to polar coordinates

Solve[{rdot Cos[θ]-r Sin[θ]θdot,rdot Sin[θ]+r Cos[θ]θdot}==flow/.{x->r Cos[θ],y->r Sin[θ]},{rdot,θdot}]//Simplify//Flatten;
flowpol={rdot,θdot}/.%

Find conditions for fixed flow signs in radial direction

Reduce[flowpol[[1]]>0,r];
Simplify[%,{r>0,0<θ<2π}]
Simplify[%,{r>0,θ==(π/4)}]
Reduce[flowpol[[1]]<0,r];
Simplify[%,{r>0,0<θ<2π}]
Simplify[%,{θ==0}]

Plot circles in StreamPlot

Show[
streamp,
ContourPlot[x^2+y^2 ==2,{x,-2,2},{y,-2,2},ContourStyle->{Thick,Red}],
ContourPlot[x^2+y^2 ==1,{x,-2,2},{y,-2,2},ContourStyle->{Thick,Red}]
]

Plot radial flow as function of θ

Plot[{flowpol[[1]]/.r->Sqrt[2]+0.1,flowpol[[1]]/.r->1-0.1},{θ,0,2π}]